Arduino ile Karaşimşek Uygulaması

Bu konuda, 8 çıkış pini kullanmak zorunda kalmadan sekiz adet büyük kırmızı LED’in Arduino’yla nasıl kullanılacağını öğreneceğiz.

Her birini bir Arduino pinine bir dirençle birlikte sekiz adet LED bağlayabilir, devremize uygun progamı yazıp çalıştırabilirdik ancak  Arduino’muzdaki pinler tükenmeye başlayacaktı. Eğer arduino’unuza bağlı pek çok şey yoksa, bunu yapmakta sorun yok – ama sıklıkla butonlar, sensörler, servolar, vb. ekipmalar kullanmak istiyoruz ve bu yöntemle birlikte kullanabileceğimiz pin kalmıyor. Bunu yapmak yerine, 74HC595 Serial to Parallel Converter adlı bir entegre kullanabiliriz. Bu entegrenin sekiz çıktışı ve entegreye bir seferde biraz veri gönderebilmek için kullandığımız üç giriş var.

Bu entegre, LED’leri sürmek için biraz yavaştır (yalnızca saniyede 8.000.000 yerine saniyede 500.000 kez LED’i değiştirebilirsiniz), ancak bu bile insanların algıladıklarından daha hızlıdır. Bu yüzden bu entegreyi kullanarak, daha az çıkış kullanmak için bu yöntemi kullanmaya değer.

Bu konuda anlatılan projeyi inşa etmek için aşağıdaki parçalara ihtiyacınız olacak.

 

Malzemelerimizi aşağıdaki gibi bağlıyoruz. Birçok bağlantı noktası olduğundan dolayı dikkat olmak konusunda sizi uyarmak isterim.

 

Muhtemelen 74HC595 çipini ilk önce yerleştirmek en kolay, çünkü hemen hemen her şey onunla bağlantılıdır. U şeklindeki küçük çentik, breadboard’un üstüne doğru gelecek şekilde yerleştirin. yani çentik yukarıya doğru ledlere doğru bakacak. Entegrenin 1 numaralı pini ise bu çentik yukarı gelecek şekilde karşıdan bakıldığında soldan başlayan 1. bacak.

Arduinomuza da aşağıdaki bağlantıları yaparız.

Arduino’dan gelen Digital 4, shift registerin 14 numaralı pinine gider
Arduino’dan gelen Digital 5, shift registerin 12 numaralı pinine gider
Arduino’dan gelen Digital 6, shift registerin 11 numaralı pinine gider

74HC595 çıkışlarının bir tanesi hariç, diğerlerinin hepsi çipin sol tarafında, dolayısıyla bağlantı kolaylığı açısından, LED’leri bu tarafa yerleştirmekte fayda var.

Entegreden sonra dirençleri yerine koyun. Dirençlerin hiçbirinin birbirine dokunmadığına dikkat etmeniz gerekir. Arduino’ya enerji vermeden önce bağlatıları tekrar kontrol etmelisiniz. Dirençlerin uçlarının birbirine dokunmadığından emin olmalısınız. Sonra, LED’leri breadboarda yerleştirin.

 

Tüm bağlantılar doğru yapıldıktan sonra, biraz aşağıda listelenen programı arduinonuza yükleyin ve deneyin. Her bir LED, tüm LED’ler yanıncaya kadar sıra ile yanmalıdır ve sonra hepsi sıra ile söner ve bu çevrim sürekli olarak tekrarlanır.

74HC595 Kaydırmalı Kaydedici (Shift Register)

Kod açıklamalarına geçmeden önce, kodun ne yapacağını anlayabilmemiz için entegrenin ne yaptığına hızlı bir şekilde göz atalım.
Entegre, kaydırmalı kaydedici (shit register) adı verilen bir türdendir. Arduino ile arasında veri alışverişi için sadece 3 pin kullanılır. Ayrıca entegreye bir de + ve – enerji beslemeleri bağlanır. Eğer entegre arduino yerine başka bir kaynaktan enerjilendirilecekse, kullanılan güç kaynağı ile arduinonun ground (-) uçlarının birbirlerine bağlanması gerekiyor. Bu işleme sıfırlama adı verilir.

Shift register, sekiz bellek yeri olarak düşünülebilir ve her bir yer, 1 veya 0 olabilir.

Bu değerlerin her birini 1 veya 0 olarak ayarlamak için, entegrenin Data (Veri) ve Clock (Saat) pinlerini kullanarak verileri besleriz.

Clock pini, veriler ile birlikte 8 pulse almalıdır. ğere daha pini o esnada 1 ise shift registere 1 itilir vey 0 ise shift regitere 0 itilir.

Tüm 8 bitlik veri alındıktan sonra, bu verilerin çıkış pinlerine yazdırılması için Latch (kapı kilidi) pini aktive edilmelidir. Latch pini, Latch registeri aktive eder ve registere kaydedilen değerler çıkış pinleri kapısına aktarılır. Yani önce çıkış pinlerinin durumunun nasıl olması isteniyorsa, o bilgi önce registere kaydedilir. Daha sonra da Latch pin aktive edilerek tüm çıkışlar aynı anda aynı değeri alır.

Entegrenin ayrıca bir OE (çıkış etkinleştirme) pini vardır, bu aynı anda çıkışları etkinleştirmek veya devre dışı bırakmak için kullanılır. Bunu PWM özellikli bir Arduino pinine bağlayabilir ve LED’lerin parlaklığını kontrol etmek için ‘analogWrite()’ ile birlikte kullanabilirsiniz. Bu pin aktif olarak düşük, bu yüzden GND’ye bağlanıyor ve çıkış pinleri sürekli olarak aktif tutuluyor.

Arduino Kod’u

Arduino, shift registere veri göndermek için özel olarak tasarlanmış ‘shiftOut()’ adlı özel bir fonksiyon içeriyor.

aşağıdaki programı kartımıza yükleyelim sonra, bu konularla ilgili açıklamalra geçelim.

/*
8 LED ve bir adet Shift Register
*/
int latchPin = 5;
int clockPin = 6;
int dataPin = 4;
byte leds = 0;
void setup()
{
pinMode(latchPin, OUTPUT);
pinMode(dataPin, OUTPUT);
pinMode(clockPin, OUTPUT);
}
void loop()
{
leds = 0;
updateShiftRegister();
delay(500);
for (int i = 0; i < 8; i++)
{
bitSet(leds, i);
updateShiftRegister();
delay(500);
}
}
void updateShiftRegister()
{
digitalWrite(latchPin, LOW);
shiftOut(dataPin, clockPin, LSBFIRST, leds);
digitalWrite(latchPin, HIGH);
}

 

Yapacağımız ilk şey, kullanacağımız üç pini tanımlamak. Bunlar, 74HC595’in LATCH, CLOCK ve DATA pinlerine bağlanacak Arduino dijital çıkışlarıdır.

int latchPin = 5;
int clockPin = 6;
int dataPin = 4;

Ardından, ‘leds’ adı verilen bir değişken tanımlanır. Bu, hangi LED’lerin o anda açık (1) veya kapalı (0) olduğu desenini tutmak için kullanılacaktır. ‘Bayt’ türündeki veriler sekiz bit kullanan sayıyı temsil eder. Her bit açık (1) veya kapalı (0) olabilir, bu nedenle sekiz LED’imizin hangisinin açık (1) veya kapalı (0) olduğunu takip etmek için mükemmel bir seçenektir.

byte leds = 0;

setup() fonksiyonu, kullandığımız üç pini dijital çıkışlar olarak ayarlar.

void setup()
{
pinMode(latchPin, OUTPUT);
pinMode(dataPin, OUTPUT);
pinMode(clockPin, OUTPUT);
}

loop() fonksiyonu, başlangıçta tüm LED’leri kapatır ve ‘leds’ değişkeninin değerini 0 olarak verir. Daha sonra ‘leds’ desenini kaydırma kaydına gönderir ve böylece tüm LED’ler sönük kalır ve  ‘updateShiftRegister’ fonksiyonu çağırılır. ‘UpdateShiftRegister’ fonksiyonunun nasıl işlediğiyle, daha sonra ilgileneceğiz.

loop() fonksiyonu, yarım saniyeliğine duraklatılır ve sonra ‘for’ döngüsü ve ‘i’ değişkeni kullanılarak 0’dan 7’ye saymaya başlar. Her defasında, Arduino  ‘bitSet()’ fonksiyonu kullanarak, ‘leds’ değişkenindeki LED’i kontrol eden biti ayarlar. Sonra da ‘updateShiftRegister’ çağırır, böylece ledler ‘leds’ değişkenini yansıtacak şekilde güncellenir.
Ardından, for döngüsü içinde delay(500); fonksiyonu ile yarım saniyelik bir gecikme olur ve for döngüsnün bir sonraki adımına geçilir, ‘i’ değişkeni içeriği bir artar ve bir sonraki LED yanar. for döngüsü içindeki koşul tamamlanana kadar bu şekilde devam eder.

void loop()
{
leds = 0;
updateShiftRegister();
delay(500);
for (int i = 0; i < 8; i++)
{
bitSet(leds, i);
updateShiftRegister();

delay(500);
}
}

‘UpdateShiftRegister’ fonksiyonu, digitalWrite() ile öncelikle latchPin’i düşük seviyeye ayarlar (1 yapar) ve böylelikle çıkış pinlerinin, şimdi yapacağımız değişiklikten etkilenmesini önler. Daha sonra Arduino fonksiyonu olan, ‘shiftOut’ ‘u çağırır. Bu fonksiyon dört parametre alır ve leds değişkeni içindeki verileri shift register içine yazar. İlk iki parametre, sırasıyla Data ve Clock için kullanılacak pinlerdir.

Üçüncü parametre, verileri yazmaya hangi uçtan başlatmak istediğinizi belirtir. Biz ‘En Az Önemli Bit’ (LSB) olarak anılan en sağdan başlayacağız. Bunun anlamı şudur; verileri seri olarak gireceğimizde, başlangıcın hangi taraftan olacağını belirtir. Yani veriler seri olarak 0. bitten başlayıp sona kadar sıra sıra mı girsin? yoksa 7. bitten başlayıp en başa kadar sırasıyla mı girsin?

diyelim ki değişkenimizin içeriği leds=10110001  olsun, LSB veya MSB tercihimize göre 74hc595 entegremizin çıkışındaki ledlerin durumu aşağıdaki gibi olur.

 

leds LSB olursa=     10110001 —————–>          1    0    0    0     1    1    0     1

 

leds MSB olursa=     10110001 —————–>         1    0    1    1      0    0    0     1

 

Son parametre olan ‘leds’ ise shift registere kaydırılacak gerçek verilerin olduğu değişken ismidir. Buraya yazacağımız değişkeni biz belirliyoruz.

Son olarak ise digitalWrite() ile  ‘latchPin’ i  yükseğe alarak (1 yaparak) çıkışlar için ayarladığımız yeni konfigürasyonu, pinlere aktarır.

void updateShiftRegister()
{
digitalWrite(latchPin, LOW);
shiftOut(dataPin, clockPin, LSBFIRST, leds);
digitalWrite(latchPin, HIGH);
}

Parlaklık Kontrol

74HC595’in henüz bahsetmediğim bir pini, ‘Çıkış Etkinleştirici (Output Enable)’ olarak adlandırılan (OE) pinidir. Bu pin numarası 13’tür ve devremizdeki breadboardda kalıcı olarak Ground’a bağlıdır. Bu pin, çıkışları etkinleştirebilen veya devre dışı bırakabilen bir anahtar görevi görür. Çıkış pinlerinin durumunu izlemek için gereken tek şey ‘aktif düşük’ olmasıdır (etkinleştirmek için Ground’a bağlanmasıdır). Yani, 5V’ye bağlıysa, tüm çıkışlar söner. Bu pin Ground’a bağlıysa 1 olması beklenen Çıkış pinleri 1’dir ve 0 olması gereken tüm çıkış pinleri 0’dır.

Bu pini ‘analogWrite()’ fonksiyonuyla birlikte kullanabilirsiniz. Bunu yapmak için, yapmanız gereken şey, 74HC595’in 13 numaralı pine olan bağlantısını değiştirmektir; böylece Ground’a bağlamak yerine, Arduino’nun 3 numaralı PWM pinine bağlayabilirsiniz.

Aşağıdaki programda, tüm LED’lerin parlaklıkları giderek artarak yanar ve azalarak söner.

/*
 LEDLER ve Shift Register – Parlaklık kontrollü
*/
int latchPin = 5;
int clockPin = 6;
int dataPin = 4;
int outputEnablePin = 3;
byte leds = 0;
void setup()
{
pinMode(latchPin, OUTPUT);
pinMode(dataPin, OUTPUT);
pinMode(clockPin, OUTPUT);
pinMode(outputEnablePin, OUTPUT);
}
void loop()
{
setBrightness(255);
leds = 0;
updateShiftRegister();
delay(500);
for (int i = 0; i < 8; i++)
{
bitSet(leds, i);

updateShiftRegister();
delay(500);
}
for (byte b = 255; b > 0; b–)
{
setBrightness(b);
delay(50);
}
}
void updateShiftRegister()
{
digitalWrite(latchPin, LOW);
shiftOut(dataPin, clockPin, LSBFIRST, leds);
digitalWrite(latchPin, HIGH);
}
void setBrightness(byte brightness) // 0 to 255
{
analogWrite(outputEnablePin, 255-brightness);
}

 

 

Umarım burada yazılanlardan faydalanırsınız…